Väärinkäyttösuodattimen hallinta

Suodattimen periaate on se, että  

1.) Testataan onko käyttäjä sellainen jota testataan

2.) testataan regex:llä added_lines ja removed_lines -muuttujia vastaan löytyykö muokkauksesta mitään kiinnostavaa. Mikäli sanalista on pitkä, niin toisistaan riippumattomat sanat alkavat blokata toisiaan. Esim. artikkeliin on lisätty teksti "ime munaa", mutta koska sieltä löytyy myös testi "saatana" aikaisemmin, niin testi ei laukea.

3.) yksittäisille sanoille / teemoille tehdyt hitaammat vertailut joiden tarkoitus on varmistaa ettei tule virheellisiä positiivisia.

article_namespace = 0

&  

(user_age<3600 | user_editcount<5)   

&

(word_match:="(\A|\b|\n| )(pimppi|pillu|paska+|seksi|vitt?un?|es jonne|huorille|huoruus|huora|kyrpä|kikkeli|pippele?i|kikuli|perse|homoja|sontaa?|kakkaa?|haista.{1,10}paska+|paskova|vammane|ime .{0,10}(muna|kulli|kyrpä)|(kulli|muna|kyrpä) .{0,10}suuhun|iso .{0,10}kyrpä|kyrvän|muna|kullit?|saatana|porno|pylly|orgasmi)";

   lcase(added_lines) rlike word_match

& !lcase(removed_lines) rlike word_match

)

&

(

   (

     paska_match:="(\A|\b|\n| )(paska|kakka|paskova|sonta)";

     paska_not_match:="albumi|EP|yhtye|sinkku|sävellys|kakkiainen";

     lcase(added_lines) rlike paska_match

   & !lcase(removed_lines) rlike paska_match

   & !lcase(old_wikitext) rlike paska_not_match

   & !lcase(old_wikitext) rlike paska_match

   )

   |

   (

     ime_match:="ime .{0,10}(kulli|muna|kyrpä)|(kulli|muna|kyrpä) .{0,10}suuhun|iso .{0,10}(kulli|muna|kyrpä)";

     lcase(added_lines) rlike ime_match

   & !lcase(removed_lines) rlike ime_match

   & !lcase(old_wikitext) rlike ime_match

   )

   |

   (

     kikkeli_match:="(\A|\b|\n| )(kikkeli|pippele?i|kikuli|kulli|kyrpä|kyrvän)";

     kikkeli_not_match:="musiikki|albumi|EP|yhtye|sinkku|sävellys|kikkelikortti";

     lcase(added_lines) rlike kikkeli_match

   & !lcase(removed_lines) rlike kikkeli_match

   & !lcase(added_lines) rlike kikkeli_not_match

   & !lcase(old_wikitext) rlike kikkeli_match

   )

   |

   (

     vittu_match:="(\A|\b|\n| )(vitt?un?|pillua?[\b ]|pimppi)";

     vittu_not_match:="musiikki|albumi|EP|yhtye|sinkku|sävellys|vittulan|runo";

     lcase(added_lines) rlike vittu_match

   & !lcase(removed_lines) rlike vittu_match

   & !lcase(old_wikitext) rlike vittu_not_match

   & !lcase(old_wikitext) rlike vittu_match

   )

   |

   (

     perse_match:="(\A|\b|\n| )(perse)";

     perse_not_match:="musiikki|albumi|EP|yhtye|sinkku|sävellys|vittulan|runo";

     perse_not_match2:="Perse|perseidit";

     lcase(added_lines) rlike perse_match

   & !lcase(removed_lines) rlike perse_match

   & !lcase(old_wikitext) rlike perse_not_match

   & !old_wikitext rlike perse_not_match2

   )

)